Contenu

# Fonctions financières - Première partie

Cette catégorie contient les fonctions financières mathématiques de LibreOffice Calc.

## AMORDEGRC

Calcule le montant de l'amortissement pour une période comptable comme amortissement dégressif. Contrairement à AMORLINC, un coefficient d'amortissement indépendant de la durée amortissable est utilisé ici.

#### Syntaxe

AMORDEGRC(coût; date_achat;première_période;sauvetage;période;taux[;base])

Coût est le coût d'acquisition.

date_achat est la date d'acquisition.

première_période est la date de fin de la première période du terme.

valeur_résiduelle est la valeur résiduelle de l'actif immobilisé en fin de durée d'amortissement.

période est la période de terme à prendre en compte.

taux est le taux d'amortissement.

base (facultatif) est choisie dans une liste d'options et indique comment l'année doit être calculée.

Base | Calcul
--- | ---
0 ou vide | Méthode américaine (NASD), 12 mois à 30 jours chaque
1 | Nombre exact de jours dans le mois, nombre exact de jours dans l'année
2 | Nombre exact de jours dans le mois, année à 360 jours
3 | Nombre exact de jours dans le mois, année à 365 jours
4 | Méthode européenne, 12 mois à 30 jours chaque

#### Exemple

Un actif a été acquis le 01/02/2020 au prix de 2000 unités monétaires. La date de fin de la première période de règlement était le 31/12/2020. La valeur de récupération de l'actif à la fin de sa durée d'amortissement sera de 10 unités monétaires. Le taux d'amortissement est de 0,1 (10 %) et l'année est calculée selon la méthode américaine (Base 0). Dans l'hypothèse d'un amortissement dégressif, quel est le montant de l'amortissement de la quatrième période d'amortissement ?

=AMORDEGRC(2000; "01/02/2020"; "31/12/2020";10;4;0,1;0) renvoie un montant d'amortissement de 163 unités monétaires.

Attention, Base 2 n'est pas pris en charge par Microsoft Excel. Par conséquent, si vous utilisez Base 2 et exportez votre document au format XLSX, il renverra une erreur lors de son ouverture dans Excel.

## AMORLINC

Calcule le montant de l'amortissement pour une période comptable comme amortissement linéaire. Si des immobilisations sont acquises pendant la période comptable, le montant proportionnel de l'amortissement est pris en considération.

#### Syntaxe

AMORLINC(coût;date_achat;première_période;sauvetage;période;taux[;base])

coût représente le coût d'acquisition.

date_achat est la date d'acquisition.

première_période est la date de fin de la première période du terme.

valeur_résiduelle est la valeur résiduelle de l'actif immobilisé en fin de durée d'amortissement.

période est la période de terme à prendre en compte.

taux est le taux d'amortissement.

base (facultatif) est choisie dans une liste d'options et indique comment l'année doit être calculée.

Base | Calcul
--- | ---
0 ou vide | Méthode américaine (NASD), 12 mois à 30 jours chaque
1 | Nombre exact de jours dans le mois, nombre exact de jours dans l'année
2 | Nombre exact de jours dans le mois, année à 360 jours
3 | Nombre exact de jours dans le mois, année à 365 jours
4 | Méthode européenne, 12 mois à 30 jours chaque

#### Exemple

Un actif a été acquis le 01/02/2020 au prix de 2000 unités monétaires. La date de fin de la première période de règlement était le 31/12/2020. La valeur de récupération de l'actif à la fin de sa durée d'amortissement sera de 10 unités monétaires. Le taux d'amortissement est de 0,1 (10 %) et l'année est calculée selon la méthode américaine (Base 0). En supposant un amortissement linéaire, quel est le montant de l'amortissement au cours de la quatrième période d'amortissement ?

=AMORLINC(2000;"01/02/2020";"31/12/2020";10;4;0.1;0) renvoie un montant d'amortissement de 200 unités monétaires.

Attention, Base 2 n'est pas pris en charge par Microsoft Excel. Par conséquent, si vous utilisez Base 2 et exportez votre document au format XLSX, il renverra une erreur lors de son ouverture dans Excel.

## DB

Renvoie l'amortissement d'un bien pour une période donnée utilisant la méthode d'amortissement fixe décroissante.

Utilisez cette forme d'amortissement pour obtenir une valeur d'amortissement plus élevée au début de l'amortissement (à l'inverse de l'amortissement linéaire). La valeur d'amortissement diminue à chaque période en fonction des amortissements déjà retirés au coût initial.

#### Syntaxe

DB(coût;sauvetage;vie;période[;mois])

coût est le coût initial d'un actif.

valeur_résiduelle est la valeur résiduelle de l'actif après amortissement.

durée définit la période pendant laquelle un actif est déprécié.

période définit la durée d'une période. Vous devez saisir la période et la durée d'utilisation avec la même unité de temps.

mois (facultatif) est le nombre de mois de la première année d'amortissement. Si l'argument est omis, ce nombre est 12.

#### Exemple

Un système informatique d'un coût initial de 25 000 unités monétaires doit être amorti sur une période de trois ans. La valeur de récupération doit être de 1 000 unités monétaires. La première période d'amortissement est de 6 mois. Quel est l'amortissement forfaitaire dégressif du système informatique dans la deuxième période, qui est une année pleine commençant à la fin du premier semestre ?

=DB(25000;1000;3;2;6) renvoie 11 037,95 unités monétaires.

## DDB

Renvoie l'amortissement d'un actif pour une période donnée selon la méthode arithmétique dégressive.

Utilisez ce type d'amortissement, et non l'amortissement linéaire, si une valeur d'amortissement initiale supérieure est requise. La valeur d'amortissement diminue avec chaque période et est généralement utilisée pour les actifs dont la perte de valeur est plus élevée peu après l'acquisition, comme les véhicules et les ordinateurs. Notez que la valeur comptable n'atteindra jamais zéro avec ce type de calcul.

#### Syntaxe

DDB(coût;sauvetage;vie;période[;facteur])

coût représente le coût d'achat initial de l'actif.

valeur_résiduelle définit la valeur résiduelle de l'actif en fin d'utilisation.

durée est le nombre de périodes (par exemple années ou mois) définissant pour combien de temps l'actif doit être utilisé.

période définit la période pour laquelle la valeur doit être calculée.

facteur (facultatif) représente le coefficient pour l'amortissement dégressif. Si l'argument est omis, le coefficient attribué est 2.

#### Exemple

Du matériel informatique d'un coût initial de 75 000 unités monétaires doit être amorti mensuellement sur 5 ans. La valeur résiduelle doit être de 1 unité monétaire et le coefficient est de 2.

=DDB(75000;1;60;12;2) = 1 721,81 unités monétaires. Ainsi, l'amortissement dégressif à taux double pendant le premier mois après l'achat est de 1 721,81 unités monétaires.

## DUREE

Calcule la durée d'un titre à revenu fixe en années.

#### Syntaxe

DUREE.MODIFIEE(terme;échéance;coupon;rendement;fréquence;[base])

terme est la date d'achat du titre.

échéance est la date à laquelle le titre arrive à échéance (expire).

coupon est le taux nominal annuel (taux d'intérêt nominal)

rendement représente le rendement annuel du titre.

fréquence est le nombre de versements d'intérêts par an (1,2 ou 4).

base (facultatif) est choisie dans une liste d'options et indique comment l'année doit être calculée.

Base | Calcul
--- | ---
0 ou vide | Méthode américaine (NASD), 12 mois à 30 jours chaque
1 | Nombre exact de jours dans le mois, nombre exact de jours dans l'année
2 | Nombre exact de jours dans le mois, année à 360 jours
3 | Nombre exact de jours dans le mois, année à 365 jours
4 | Méthode européenne, 12 mois à 30 jours chaque

#### Exemple

Un titre a été acquis le 1/1/2001 et le terme de l'échéance a été fixé au 1/1/2006. L'intérêt nominal est de 8%, le rendement s'élève à 9,0% et les intérêts sont versés tous les semestres (fréquence = 2). La base de comptage des jours est réelle (base = 3). Quelle est la durée modifiée ?

=DUREE.MODIFIEE("01/01/2001";"01/01/2006";0,08;0,09;2;3) renvoie 4,2 ans.

## INTERET.ACC

Calcule les intérêts courus d'un titre en cas de versements périodiques.

#### Syntaxe

INTERET.ACC(date;premier_intérêt;terme;taux;[par];fréquence[;base])

émission (requis) est la date d'émission du titre.

premier_coupon (requis) représente la date de premier intérêt du titre.

liquidation (requis) est la date à laquelle les intérêts accumulés jusque là doivent être calculés.

taux (requis) représente le taux nominal annuel de l'intérêt (taux d'intérêt du coupon)

par (facultatif) est la valeur de la sécurité. Si elle est omise, une valeur par défaut de 1000 est utilisée.

Nous vous recommandons de toujours spécifier la valeur requise pour l'argument par de INTERET.ACC, plutôt que de permettre à Calc d'appliquer une valeur arbitraire par défaut. Cela rendra la formule plus facile à comprendre et à entretenir.

fréquence (requis) est le nombre de versements d'intérêts par an (1,2 ou 4).

base (facultatif) est choisie dans une liste d'options et indique comment l'année doit être calculée.

Base | Calcul
--- | ---
0 ou vide | Méthode américaine (NASD), 12 mois à 30 jours chaque
1 | Nombre exact de jours dans le mois, nombre exact de jours dans l'année
2 | Nombre exact de jours dans le mois, année à 360 jours
3 | Nombre exact de jours dans le mois, année à 365 jours
4 | Méthode européenne, 12 mois à 30 jours chaque

#### Exemple

Un titre est émis le 28/2/2001, le premier coupon est daté du 31/8/2001, la date de liquidation est le 1/5/2001. L'intérêt nominal est de 0,1 ou 10%, la valeur nominale est de 1000 unités monétaires. Les intérêts sont versés tous les semestres (fréquence = 2). La base est la méthode américaine (0). Montant des intérêts à échoir ?

=INTERET.ACC("28/02/2001";"31/08/2001";"01/05/2001";0,1;1000;2;0) renvoie 16,94444.

## INTERET.ACC.MAT

Calcule les intérêts courus d'un titre en cas de versement unique à la date d'échéance.

#### Syntaxe

INTERET.ACC.MAT(date;terme;taux[;par][;base])

émission (requis) est la date d'émission du titre.

liquidation (requis) est la date à laquelle les intérêts accumulés jusque là doivent être calculés.

taux (requis) est le taux annuel nominal de l'intérêt (taux d'intérêt du coupon).

par (facultatif) est la valeur de la sécurité. Si elle est omise, une valeur par défaut de 1000 est utilisée.

Nous vous recommandons de toujours spécifier la valeur requise pour l'argument par de INTERET.ACC.MAT, plutôt que de permettre à Calc d'appliquer une valeur arbitraire par défaut. Cela rendra la formule plus facile à comprendre et à entretenir.

base (facultatif) est choisie dans une liste d'options et indique comment l'année doit être calculée.

Base | Calcul
--- | ---
0 ou vide | Méthode américaine (NASD), 12 mois à 30 jours chaque
1 | Nombre exact de jours dans le mois, nombre exact de jours dans l'année
2 | Nombre exact de jours dans le mois, année à 360 jours
3 | Nombre exact de jours dans le mois, année à 365 jours
4 | Méthode européenne, 12 mois à 30 jours chaque

#### Exemple

Un titre est émis le 1/4/2001, la date de liquidation est le 15/6/2001. L'intérêt nominal est de 0,1 ou 10%, la valeur nominale est de 1000 unités monétaires. La base de comptage des jours est réelle (3). Montant des intérêts à échoir ?

=INTERET.ACC.MAT("01/04/2001";"15/06/2001";0,1;1000;3) renvoie 20,54795.

## ISPMT

Calcule le niveau d'intérêt de paiements à amortissement fixe.

#### Syntaxe

ISPMT(taux;période;périodes_total;investissement)

taux détermine le taux d'intérêt périodique.

période représente le nombre d'amortissement pour le calcul des intérêts.

périodes_total représente le nombre total de périodes d'amortissement.

investissement représente le montant de l'investissement.

#### Exemple

Pour un crédit d'un montant de 120 000 unités monétaires sur deux ans avec remboursements mensuels, à un taux d'intérêt de 12 %, le montant des intérêts après 18 mois est recherché.

=ISPMT(1%;18;24;120000) = -300 unités monétaires. L'intérêt mensuel après 1,5 années se monte à 300 unités monétaires.

## SYD

Renvoie le taux d'amortissement arithmétique dégressif.

Utilisez cette fonction pour calculer le montant de l'amortissement d'un objet pour une période donnée sur la durée totale de l'amortissement. L'amortissement arithmétique dégressif réduit le montant de l'amortissement d'une période à l'autre d'un montant constant.

#### Syntaxe

SYD(coût;valeur_résiduelle;durée;période)

coût est le coût initial d'un actif.

valeur_résiduelle est la valeur résiduelle d'un actif après amortissement.

durée est la durée de vie du bien, définissant le nombre de périodes au cours desquelles l'actif est amorti.

période définit la période pour laquelle l'amortissement doit être calculé.

#### Exemple

Du matériel vidéo d'un coût initial de 50 000 unités monétaires doit être amorti annuellement sur 5 ans. La valeur résiduelle doit être de 10 000 unités monétaires. Amortissement pour la première année.

=SYD(50000;10000;5;1)=13 333,33 unités monétaires. Le montant de l'amortissement pour la première année est de 13 333,33 unités monétaires.

Le mieux est de définir une table d'amortissement qui vous permettra de consulter en un coup d'oeil tous les taux d'amortissement par période. Si vous saisissez les différentes formules de calcul d'amortissement de LibreOffice Calc les unes à la suite des autres, vous pourrez définir la formule la mieux adaptée à votre cas. Voici un exemple de table :

| A | B | C | D | E
1 | coût initial | valeur résiduelle | durée de vie | durée | SYD dépréciation
2 | 50 000 unités monétaire | 10 000 unités monétaire | 5 | 1 | 13 333,33 unités monétaire
3 |  |  |  | 2 | 10 666,67 unités monétaire
4 |  |  |  | 3 | 8 000,00 unités monétaire
5 |  |  |  | 4 | 5 333,33 unités monétaire
6 |  |  |  | 5 | 2 666,67 unités monétaire
7 |  |  |  | 6 | 0,00 unités monétaire
8 |  |  |  | 7 |
9 |  |  |  | 8 |
10 |  |  |  | 9 |
11 |  |  |  | 10 |
12 |  |  |  |  |
13 | >0 |  |  | Total | 40 000,00 unités monétaire

La formule en E2 est la suivante :

=SYD($A$2;$B$2;$C$2;D2)

Cette formule est dupliquée de la colonne E jusqu'à E11 (sélectionnez E2, puis faites glisser l'angle inférieur droit vers le bas à l'aide de la souris).

La formule permettant de contrôler par addition tous les montants d'amortissement se trouve dans la cellule E13. Elle utilise la fonction SOMME.SI, puisque les valeurs négatives en E8:E11 ne peuvent pas être prises en compte. La condition >0 se trouve dans la cellule A13. La formule en E13 est la suivante :

=SOMME.SI(E2:E11;A13)

Vous pouvez à présent consulter l'amortissement sur 10 ans, le consulter pour une valeur résiduelle de 1 unité monétaire, ou encore saisir d'autres coûts d'achat initiaux, etc.

## TAUX.EFFECTIF

Renvoie le taux d'intérêt annuel net pour un taux d'intérêt nominal.

Le taux d'intérêt nominal étant basé sur une échéance des intérêts en fin de période de calcul, alors que les intérêts sont très souvent payés mensuellement ou trimestriellement (ou à un autre moment) avant la fin de la période de calcul (donc payés par avance), les intérêts effectifs augmentent avec le nombre de paiements échelonnés des intérêts.

#### Syntaxe

TAUX.EFFECTIF(nom;P)

nom est l'intérêt nominal.

P représente le nombre de paiements des intérêts périodiques par an.

#### Exemple

Si les intérêts nominaux annuels sont de 9,75% et que quatre périodes de calcul des intérêts sont prévues, quel est le taux d'intérêt réel (intérêts effectifs) ?

=TAUX.EFFECTIF(9,75%;4) = 10,11%. Le taux effectif annuel est donc de 10,11%.

## TAUX.EFFECTIF_ADD

Calcule le taux d'intérêt effectif annuel en fonction du taux d'intérêt nominal et du nombre de paiements d'intérêts par an.

Les fonctions dont les noms se terminent par _ADD ou _EXCEL2003 renvoient le même résultat que les fonctions correspondantes Microsoft Excel 2003 sans le suffixe. Utilisez les fonctions sans suffixe pour obtenir des résultats basés sur les standards internationaux.

#### Syntaxe

TAUX.EFFECTIF_ADD(taux_nominal;NPA)

taux_nominal est le taux nominal annuel de l'intérêt.

NPA représente le nombre de paiements des intérêts périodiques par an.

#### Exemple

Intérêt effectif pour un intérêt nominal de 5,25% et des versements trimestriels.

=TAUX.EFFECTIF_ADD(0,0525;4) renvoie 0,053543 ou 5,3543%.

## TAUX.ESCOMPTE

Calcule l'escompte d'un titre en pourcentage.

#### Syntaxe

TAUX.ESCOMPTE(terme;échéance;prix;remboursement;[base])

terme est la date d'achat du titre.

échéance est la date à laquelle le titre arrive à échéance (expire).

prix est le prix du titre pour 100 unités monétaires de la valeur nominale.

remboursement est la valeur de remboursement du titre pour 100 unités monétaires de la valeur nominale.

base (facultatif) est choisie dans une liste d'options et indique comment l'année doit être calculée.

Base | Calcul
--- | ---
0 ou vide | Méthode américaine (NASD), 12 mois à 30 jours chaque
1 | Nombre exact de jours dans le mois, nombre exact de jours dans l'année
2 | Nombre exact de jours dans le mois, année à 360 jours
3 | Nombre exact de jours dans le mois, année à 365 jours
4 | Méthode européenne, 12 mois à 30 jours chaque

#### Exemple

Un titre a été acquis le 25/1/2001 et le terme de l'échéance a été fixé au 15/11/2001. La valeur négociable (prix d'achat) est 97 et la valeur de remboursement 100. La base de comptage des jours est réelle (3). Montant du rabais (escompte) ?

=TAUX.ESCOMPTE("25/01/2001";"15/11/2001";97;100;3) renvoie about 0,0372 or 3,72 pour cent.

## TRI

Calcule le taux de rentabilité interne d'un investissement. Les valeurs représentent le flux de trésorerie à intervalles réguliers ; au moins une valeur doit être négative (dépenses) et au moins une valeur doit être positive (recettes).

Si le paiement prend place à intervalles irréguliers, utilisez la fonction TRI.PAIEMENTS.

#### Syntaxe

TRI(valeurs[;estimation])

valeurs représente une matrice contenant les valeurs.

estimation (facultatif) est la valeur estimée. Une méthode itérative est utilisée pour calculer le taux de rentabilité interne. Si vous ne pouvez fournir que quelques valeurs, il est préférable que vous réalisiez une estimation initiale pour permettre l'itération.

Cette fonction ignore tout texte ou cellule vide dans une plage de données. Si vous soupçonnez des résultats erronés de cette fonction, recherchez du texte dans les plages de données. Pour mettre en évidence le contenu du texte dans une plage de données, utilisez la fonction Mise en évidence des valeurs.

#### Exemple

Dans l'hypothèse ou le contenu des cellules est A1=-10000, A2=3500, A3=7600 et A4=1000, la formule =TRI(A1:A4) donne un résultat de 11,33%.

En raison du calcul par itération utilisé, il est possible que la fonction TRI échoue et renvoie Err :523, avec "Erreur : le calcul ne converge pas" dans la barre d'état. Dans ce cas, réessayer avec une nouvelle valeur pour l'estimation.

## VA

Renvoie la valeur actuelle d'un investissement provenant d'une série de paiements réguliers.

Utilisez cette fonction pour calculer la somme d'argent que vous devez placer pour qu'un montant fixe (annuité) soit versé pendant un nombre de périodes donné. Vous pouvez indiquer de manière facultative le montant qui devra rester à la fin de cette période et pouvez aussi spécifier si le montant à payer doit l'être à chaque fois en début ou en fin de période.

Les valeurs peuvent être saisies sous forme de nombres, d'expressions ou de références. Si vous bénéficiez, par exemple, d'intérêts annuels de 8%, mais que vous souhaitiez définir des périodes mensuelles, saisissez dans le champ Taux 8%/12. LibreOffice Calc calcule automatiquement le bon coefficient.

#### Syntaxe

VA(taux;NPM;VPM[;VC][;type])

taux définit le taux d'intérêt par période.

NPM est le nombre total de périodes (période de paiement).

VPM est le versement régulier fait par période.

VC (facultatif) détermine la valeur future restant après le paiement de la dernière échéance.

type (facultatif) représente l'échéance. Type = 1 représente l'échéance au début d'une période, Type = 0 (prédéfini) l'échéance à la fin.

Dans les fonctions LibreOffice Calc, les paramètres marqués comme "facultatifs" peuvent être ignorés lorsqu'ils ne sont pas suivis d'autres paramètres. Par exemple, dans une fonction comportant quatre paramètres, où les deux derniers paramètres sont marqués comme "facultatifs", le paramètre 4 ou les paramètres 3 et 4 peuvent être ignorés, mais le paramètre 3 seul ne peut être ignoré.

#### Exemple

Valeur actuelle d'un investissement pour un versement mensuel de 500 unités monétaires et un taux d'intérêt de 8 % par an. La période de paiement étant de 48 mois et la valeur finale de 20.000 unités monétaires.

=VA(8%/12;48;500;20000) = -35 019,37 unités monétaires. Sous les conditions nommées, vous devez déposer 35 019,37 unités monétaires aujourd'hui si vous voulez recevoir 500 unités monétaires par mois pendant 48 mois et avoir 20 000 unités monétaires de reste à la fin. Une vérification croisée montre que 48 x 500 unités monétaires + 20 000 unités monétaires = 44 000 unités monétaires. La différence entre ce montant et les 35 000 unités monétaires déposées représente les intérêts payés.

Ne saisissez pas les valeurs directement, mais sous forme de référence dans la formule ; vous pourrez ainsi établir des estimations à partir de scénarios " Comment-si ". Pensez à définir les références des constantes en tant que références absolues. Vous trouverez des exemples pour ce type d'application dans les fonctions d'amortissement.

## VALEUR.NOMINALE

Calcule le montant d'un versement pour un titre à revenu fixe à un moment donné.

#### Syntaxe

VALEUR.NOMINALE(terme;échéance;investissement;escompte[;base])

terme est la date d'achat du titre.

échéance est la date à laquelle le titre arrive à échéance (expire).

investissement est le montant de l'achat.

escompte est le pourcentage d'escompte sur l'acquisition du titre.

base (facultatif) est choisie dans une liste d'options et indique comment l'année doit être calculée.

Base | Calcul
--- | ---
0 ou vide | Méthode américaine (NASD), 12 mois à 30 jours chaque
1 | Nombre exact de jours dans le mois, nombre exact de jours dans l'année
2 | Nombre exact de jours dans le mois, année à 360 jours
3 | Nombre exact de jours dans le mois, année à 365 jours
4 | Méthode européenne, 12 mois à 30 jours chaque

#### Exemple

Date de liquidation : 15 février 1999, terme de l'échéance : 15 mai 1999, montant de l'investissement : 1000 unité monétaires, l'escompte s'élève à 5,75 % et la base est réelle/360 = 2.

Calcul du montant du versement :

=VALEUR.NOMINALE("15/02/1999";"15/05/1999";1000;0,0575;2) renvoie 1014,420266.

Fonctions financières - Deuxième partie

Fonctions financières - Troisième partie

Fonctions par catégories