Contenu

# Fonctions de matrice

Cette catégorie contient les fonctions de matrice.

## Qu'est-ce qu'une matrice ?

Une matrice est une plage de cellules liées dans une feuille contenant des valeurs. Une plage carrée composée de 3 lignes et de 3 colonnes est une matrice 3 x 3 :

| A | B | C | D | E
1 | 7 | 31 | 33
2 | 95 | 17 | 2
3 | 5 | 10 | 50
4

La matrice la plus petite qui puisse exister est la matrice 1 x 2 ou 2 x 1 avec deux cellules adjacentes.

## Qu'est-ce qu'une formule de matrice ?

Il s'agit d'une formule permettant d'évaluer les différentes valeurs d'une plage de cellules. Une formule de matrice se différencie des autres formules par le fait que, contrairement à celles-ci, elle est capable de traiter plusieurs valeurs à la fois.

Une formule de matrice peut non seulement traiter plusieurs valeurs, mais elle peut aussi renvoyer plusieurs valeurs. Le résultat d'une formule de matrice est aussi une matrice.

Pour multiplier les valeurs dans les cellules individuelles par 10 dans la matrice ci-dessus, vous n'avez pas besoin d'appliquer une formule à chaque cellule individuelle ou chaque valeur. Vous n'avez besoin que d'une simple formule de matrice. Sélectionnez une plage de 3x3 cellules sur une autre zone de la feuille de calcul, saisissez la formule =10*A1:C3 et confirmez cette saisie en utilisant la combinaison de touches Commande Ctrl+Maj+Entrée. Le résultat est une matrice de 3x3 dans laquelle les valeurs individuelles de la plage de cellules (A1:C3) sont multipliées par un facteur de 10.

Vous pouvez appliquer d'autres opérateurs que la multiplication à la plage de référence (matrice). Avec LibreOffice Calc, vous pouvez additionner (+), soustraire (-), multiplier (*), diviser (/) et également utiliser des exposants (^), des concaténations (&) et des comparaisons (=, <>, <, >, <=, >=). Une fois la formule de matrice saisie, les opérateurs peuvent s'appliquer séparément à chaque valeur de la plage de cellules et afficher le résultat sous forme de matrice.

Les opérateurs de comparaison dans une formule matricielle traitent les cellules vides de la même façon que dans une formule normale, c'est à dire comme zéro ou comme une chaîne vide. Par exemple, si les cellules A1 et A2 sont vides, les formules matricielles {=A1:A2=""} et {=A1:A2=0} vont toutes deux renvoyer une matrice d'une colonne et deux lignes de cellules contenant VRAI.

### Quand utiliser une formule matricielle ?

Vous utiliserez une formule de matrice lorsque vous devrez effectuer plusieurs fois le même calcul en utilisant des valeurs différentes. Si vous décidez de changer de méthode de calcul par la suite, il vous suffira de mettre à jour la formule. Pour ajouter une formule de matrice, sélectionnez l'intégralité d'une plage de matrice, puis modifiez la formule de matrice selon les besoins.

Les formules de matrice présentent aussi l'avantage d'économiser l'espace disque lorsque le calcul porte sur plusieurs valeurs, car elles consomment peu de mémoire. Capables de traiter plusieurs plages de cellules en une seule opération, elles constituent en outre un outil précieux pour réaliser des calculs complexes. LibreOffice peut appliquer diverses fonctions mathématiques aux matrices, par exemple PRODUITMAT pour multiplier deux matrices, ou SOMMEPROD pour calculer les produits scalaires de deux matrices.

## Utilisation des formules de matrice dans LibreOffice Calc

### Intersection implicite des formules de matrice

Vous pouvez également créer une formule "normale" dans laquelle la plage de référence, telle que les paramètres, indique une formule de matrice. Cette formule est aussi connu comme "intersection implicite" d'une formule de matrice. Le résultat obtenu correspond à l'intersection de la plage de référence et des lignes ou colonnes contenant la formule. S'il n'y a pas d'intersection ou que la plage au niveau de l'intersection couvre plusieurs lignes ou colonnes, un message d'erreur #VALEUR! s'affiche. L'exemple suivant illustre ce concept :

Dans la table ci-dessus, placez la formule de matrice en D1 :

{=A1:A3 + 100}

Les cellules D1, D2, D3 ont comme valeurs 107, 195, 105 respectivement.

Insérez la formule ci-dessous en E2, ne la saisissez pas comme formule de matrice.

=A1:A3 + 100

Les cellules E1 et E3 sont vides, la cellule E2 a la valeur 195. C'est l'intersection implicite des formules de matrice.

Insérez la formule suivante en E4, comme en E2.

=A1:A3 + 100

La cellule E4 affiche #VALEUR!. La ligne 4 est en dehors de la plage A1:A3 de la formule.

### Création de formules de matrice

Lorsque vous créez une formule de matrice à l'aide de l'assistant Fonctions, vous devez cocher la case Matrice à chaque fois pour que les résultats soient renvoyés dans une matrice. Dans le cas contraire, seule la valeur de la cellule supérieure gauche de la matrice calculée est renvoyée.

Si vous saisissez une formule de matrice directement dans une cellule, vous devez utiliser la combinaison de touches Maj+Commande Ctrl+Entrée au lieu de la touche Entrée. C'est seulement ainsi que la formule devient une formule de matrice.

Dans LibreOffice Calc, les formules de matrice s'affichent entre accolades. Cependant, vous ne pouvez pas créer de formule en saisissant manuellement ces accolades.

Les cellules composant une matrice de résultat sont automatiquement protégées contre les modifications. Vous pouvez cependant éditer, supprimer ou copier la formule en sélectionnant la totalité de la plage de cellules de la matrice.

### Utilisation des constantes de matrice en ligne dans les formules

Calc prend en charge les constantes de matrice en ligne dans les formules. Une matrice en ligne est entourée par des accolades '{' et '}'. Les éléments peuvent être soit un nombre (y compris les nombres négatifs), une constante logique (VRAIE, FAUX) ou une chaîne de texte. Les expressions non constantes ne sont pas autorisées. La matrice peut être saisie avec une ou plusieurs lignes et une ou plusieurs colonnes. Toutes les lignes doivent avoir le même nombre d'éléments, toutes les colonnes doivent avoir le même nombre d'éléments.

Le séparateur de colonne (séparant les éléments dans une ligne) et le séparateur de ligne sont dépendants de la langue et du paramétrage local. Mais dans cette aide, le point-virgule ";" et le symbole pipe "|" sont utilisés pour indiquer les séparateurs de colonnes et de lignes, respectivement. Par exemple, dans la locale Anglaise, la virgule "," est utilisée comme séparateur de colonne, alors que le point-virgule ";" est utilisé comme séparateur de ligne.

Vous pouvez afficher et modifier le séparateur de ligne et de colonne sous LibreOffice - Préférences Outils - Options - Calc - Formule - Séparateurs.

Les matrices ne peuvent pas être imbriquées.

Exemples :

={1;2;3}

Une matrice d'une ligne consistant en trois chiffres 1, 2, et 3.

Pour saisir cette constante de matrice, sélectionnez trois cellules dans une ligne, puis saisissez la formule ={1;2;3} en utilisant des accolades et des points virgules, puis appuyez sur Commande Ctrl+Maj+Entrée.

={1;2;3|4;5;6}

Une matrice de deux lignes contenant chacune trois valeurs.

={0;1;2|FAUX;VRAI;"deux"}

Une matrice de données mélangées.

=SIN({1;2;3})

Saisi comme une formule de matrice, donnera le résultat de trois calculs de SIN avec les arguments 1, 2, et 3.

### Édition de formules de matrice

1. Sélectionnez la plage de cellules ou la matrice contenant la formule de matrice. Pour sélectionner la matrice entière, positionnez le curseur de cellule à l'intérieur de la plage de matrice, puis appuyez sur Commande Ctrl+/, où / est le symbole de division sur le clavier numérique.

2. Appuyez sur F2 ou placez le curseur sur la ligne de saisie. Ces deux actions permettent d'éditer la formule.

3. Après avoir fait les modifications, appuyez sur Commande Ctrl+Maj+Entrée.

Vous pouvez formater les différentes parties d'une matrice. Vous pouvez par exemple changer la couleur de la police. Sélectionnez une plage de cellules, puis modifiez l'attribut souhaité.

### Suppression de formules de matrice

1. Sélectionnez la plage de cellules ou la matrice contenant la formule de matrice. Pour sélectionner la matrice entière, positionnez le curseur de cellule à l'intérieur de la plage de matrice, puis appuyez sur Commande Ctrl+/, où / est le symbole de division sur le clavier numérique.

2. Appuyez sur Supprimer pour supprimer le contenu de la matrice, y compris la formule de la matrice, ou appuyez sur Retour arrière et cela fait apparaître la boîte de dialogueSupprimer le contenu. Sélectionnez Formule ou Tout supprimer et cliquez sur OK.

### Copie des formules de matrice

1. Sélectionnez la plage de cellules ou la matrice contenant la formule.

2. Appuyez sur F2 ou placez le curseur sur la ligne de saisie.

3. Copiez la formule dans la ligne de saisie en appuyant sur Commande Ctrl+C.

4. Sélectionnez la plage de cellules dans laquelle vous souhaitez insérer la formule, puis appuyez sur F2 ou positionnez le curseur dans la ligne de saisie.

5. Copiez la formule en appuyant sur Commande Ctrl+V dans l'espace sélectionné et confirmez en appuyant sur Commande Ctrl+Maj+Entrée. La plage sélectionnée contient maintenant la formule de matrice.

### Ajustement d'une plage de matrice

Si vous souhaitez éditer la matrice de résultat, procédez comme suit :

1. Sélectionnez la plage de cellules ou la matrice contenant la formule.

2. Sous la sélection, à droite s'affiche une petite icône qui permet d'agrandir ou de réduire la plage à l'aide de la souris.

Lorsque vous ajustez la plage d'une matrice, la formule de matrice n'est pas ajustée automatiquement. Seule la plage dans laquelle s'affiche le résultat est modifiée.

En maintenant la touche Commande Ctrl, vous pouvez créer une copie de la formule de matrice dans une plage donnée.

### Calculs conditionnels de matrice

On définit comme calcul conditionnel de matrice une matrice ou une formule de matrice comprenant une fonction SI() ou CHOISIR(). L'argument de condition de la formule est une référence de zones ou un résultat de matrice.

Dans l'exemple suivant, le test >0 de la formule {=SI(A1:A3>0;"oui";"non")} est appliqué à chaque cellule de la plage A1:A3 et le résultat est copié dans la cellule correspondante.

| A | B (formule) | B (résultat)
1 | 1 | {=SI(A1:A3>0;"oui";"non")} | oui
2 | 0 | {=SI(A1:A3>0;"oui";"non")} | non
3 | 1 | {=SI(A1:A3>0;"oui";"non")} | oui

Les fonctions suivantes permettent une gestion des matrices forcées : COEFFICIENT.CORRELATION, COVARIANCE, PREVISION, TEST.F, ORDONNEE.ORIGINE, DETERMAT, INVERSEMAT, PRODUITMAT, MODE, PEARSON, PROBABILITE, COEFFICIENT.DETERMINATION, PENTE, ERREUR.TYPE.XY, SOMMEPROD, SOMME.X2MY2, SOMME.X2PY2, SOMME.XMY2, TEST.STUDENT. Si vous utilisez des références de zones comme arguments lorsque vous appelez ces fonctions, celles-ci se comporteront comme des fonctions de matrices. Le tableau ci-dessous illustre une exemple de gestion des matrices forcées :

| A | B (formule) | B (résultat) | C (formule de matrice forcée) | C (résultat)
1 | 1 | =A1:A2+1 | 2 | =SOMMEPROD(A1:A2+1) | 5
2 | 2 | =A1:A2+1 | 3 | =SOMMEPROD(A1:A2+1) | 5
3 |  | =A1:A2+1 | #VALEUR ! | =SOMMEPROD(A1:A2+1) | 5

## CROISSANCE

Calcule les points d'une tendance exponentielle dans une matrice.

#### Syntaxe

CROISSANCE(données_Y[;[données_X][;[nouvelles_données_X][;type_fonction]]])

données_Y représente la matrice de données Y.

données_X (facultatif) représente la matrice de données X.

nouvelles_données_X (facultatif) représente la matrice de données X dans laquelle les valeurs sont recalculées.

type_fonction (facultatif). Si type_fonction = 0, les fonctions de la forme y = m^x seront calculées. Sinon, les fonctions y = b*m^x seront calculées.

Dans les fonctions LibreOffice Calc, les paramètres marqués comme "facultatifs" peuvent être ignorés lorsqu'ils ne sont pas suivis d'autres paramètres. Par exemple, dans une fonction comportant quatre paramètres, où les deux derniers paramètres sont marqués comme "facultatifs", le paramètre 4 ou les paramètres 3 et 4 peuvent être ignorés, mais le paramètre 3 seul ne peut être ignoré.

Informations complémentaires en haut de cette page.

#### Exemple

Cette fonction renvoie une matrice et est traitée de la même façon que les autres fonctions matricielles. Sélectionnez une plage dans laquelle vous souhaitez que les réponses apparaissent et sélectionnez la fonction. Sélectionnez données_Y. Saisissez n'importe quel autre paramètre, cochez Matrice et cliquez sur OK.

## DETERMAT

Renvoie le déterminant d'une matrice. Cette fonction renvoie une valeur dans la cellule active ; il n'est pas nécessaire de définir une plage pour les résultats.

#### Syntaxe

DETERMAT(matrice)

matrice représente une matrice carrée dans laquelle sont définis les déterminants.

Une introduction générale à l'utilisation des fonctions de matrice est disponible en haut de cette page.

Informations complémentaires en haut de cette page.

## DROITEREG

Renvoie une table de statistiques pour une ligne droite qui s'adapte au mieux à un ensemble de données.

#### Syntaxe

DROITEREG(données_Y[;données_X[;type_linéaire[;stats]]])

données_Y est une plage de ligne ou de colonne unique spécifiant les coordonnées y dans un ensemble de points de données.

données_X est une plage de colonne ou de ligne unique correspondante, spécifiant les coordonnées x. Si données_X est omis, par défaut il est 1, 2, 3, ..., n. S'il y a plus d'un ensemble de variables, données_X peut-être une plage avec de multiples lignes ou colonnes correspondantes.

DROITEREG trouve une ligne droite y = a + bx qui s'adapte au mieux aux données, en utilisant une régression linéaire (la méthode des "moindres carrés"). Avec plus d'un ensemble de variables, la ligne droite est de la forme y = a + b1x1 + b2x2 ... + bnxn.

Si Type linéaire est FAUX, la ligne droite trouvée est forcée à passer par l'origine (la constante a est zéro ; y = bx). S'il est omis, Type linéaire est VRAI par défaut (la ligne n'est pas forcée à passer par l'origine).

Si stats est omis ou FAUX, seule la ligne supérieure de la table de statistiques est renvoyée. S'il est VRAI, la table entière est renvoyée.

DROITEREG renvoie une table (matrice) de statistiques comme ci-dessous et doit être saisie comme une formule de matrice (par exemple en utilisant Commande Ctrl+Maj+Entrée à la place de la touche Entrée seule).

Dans les fonctions LibreOffice Calc, les paramètres marqués comme "facultatifs" peuvent être ignorés lorsqu'ils ne sont pas suivis d'autres paramètres. Par exemple, dans une fonction comportant quatre paramètres, où les deux derniers paramètres sont marqués comme "facultatifs", le paramètre 4 ou les paramètres 3 et 4 peuvent être ignorés, mais le paramètre 3 seul ne peut être ignoré.

Informations complémentaires en haut de cette page.

#### Exemple

Cette fonction renvoie une matrice et est traitée de la même façon que les autres fonctions matricielles. Sélectionnez une plage pour les réponses et ensuite la fonction. Sélectionnez données_Y. Si vous le souhaitez, vous pouvez saisir d'autres paramètres. Sélectionnez Matrice et cliquez sur OK.

Les résultats renvoyés par le système (si stats = 0), afficheront au moins la pente de la courbe de régression et son intersection avec l'axe Y. Si stats n'est pas égal à 0, d'autres résultats seront affichés.

### Autres résultats de DROITEREG :

Étudiez les exemples ci-dessous :

| A | B | C | D | E | F | G
1 | x1 | x2 | y |  | valeur DROITEREG |  |
2 | 4 | 7 | 100 |  | 4,17 | -3,48 | 82,33
3 | 5 | 9 | 105 |  | 5,46 | 10,96 | 9,35
4 | 6 | 11 | 104 |  | 0,87 | 5,06 | #NA
5 | 7 | 12 | 108 |  | 13,21 | 4 | #NA
6 | 8 | 15 | 111 |  | 675,45 | 102,26 | #NA
7 | 9 | 17 | 120 |  |  |  |
8 | 10 | 19 | 133 |  |  |  |

La colonne A contient plusieurs valeurs X1, la colonne B plusieurs valeurs X2 et la colonne C les valeurs Y. Vous avez déjà saisi ces valeurs dans la feuille de calcul. Vous avez maintenant paramétré E2:G6 dans cette même feuille et activé l'Assistant Fonctions. Pour activer la fonction DROITEREG, vous devez cocher la case Matrice dans l'Assistant Fonctions. Ensuite, sélectionnez les valeurs suivantes dans la feuille de calcul (ou saisissez-les à l'aide du clavier) :

données_Y est C2:C8

données_X est A2:B8

Type_linéaire et stats sont tous deux paramétrés sur 1.

Dès que vous cliquez sur OK, LibreOffice Calc complète l'exemple ci-dessus avec les valeurs DROITEREG, comme le montre l'exemple.

La formule dans la barre de formule correspond à chaque cellule de la matrice DROITEREG {=DROITEREG(C2:C8;A2:B8;1;1)}

Ceci représente les valeurs calculées par DROITEREG :

E2 et F2 : pente m de la courbe de régression y=b+m*x pour les valeurs x1 et x2. Les valeurs sont données dans l'ordre inverse ; c'est à dire, la pente pour x2 en E2 et la pente pour x1 en F2.

G2 : Intersection b avec l'axe y.

E3 et F3 : erreur standard de la valeur de la pente.

G3 : erreur standard de l'ordonnée d'origine

E4 : COEFFICIENT.DETERMINATION

F4 : erreur standard de régression calculée pour la valeur Y.

E5 : valeur F de l'analyse de la variance.

F5 : degré de liberté pour l'analyse de la variance.

E6 : somme des carrés des écarts des valeurs Y estimées depuis leur moyenne linéaire.

F6 : somme des carrés des écarts de la valeur Y estimée depuis les valeurs Y données.

Informations complémentaires en haut de cette page.

## FREQUENCE

Indique la distribution fréquentielle dans une matrice à une seule colonne. La fonction compte le nombre de valeurs de la matrice des données qui sont comprises entre les valeurs définies par la matrice des classes.

#### Syntaxe

FREQUENCE(données;classes)

données représente la référence aux valeurs à compter.

classes représente la matrice des valeurs limites.

Cette fonction ignore tout texte ou cellule vide dans une plage de données. Si vous soupçonnez des résultats erronés de cette fonction, recherchez du texte dans les plages de données. Pour mettre en évidence le contenu du texte dans une plage de données, utilisez la fonction Mise en évidence des valeurs.

Une introduction générale à l'utilisation des fonctions de matrice est disponible en haut de cette page.

#### Exemple

Dans la table suivante, la colonne A présente des valeurs de mesure non triées. La colonne B indique la limite supérieure que vous avez fixée pour les classes selon lesquelles vous voulez diviser les données de la colonne A. Selon la limite saisie pour B1, par exemple, la fonction FREQUENCE doit renvoyer le nombre de valeurs mesurées inférieures ou égales à 5. La limite donnée pour B2 étant 10, la fonction FREQUENCE renvoie comme second résultat le nombre de valeurs mesurées supérieures à 5, ou inférieures ou égales à 10. Le texte saisi dans B6, ">25", est à titre de référence seulement.

| A | B | C
1 | 12 | 5 | 1
2 | 8 | 10 | 3
3 | 24 | 15 | 2
4 | 11 | 20 | 3
5 | 5 | 25 | 1
6 | 20 | >25 | 1
7 | 16 |  |
8 | 9 |  |
9 | 7 |  |
10 | 16 |  |
11 | 33 |  |

Sélectionnez dans une seule colonne la plage dans laquelle s'affichera la fréquence des valeurs selon les limites des classes. Vous devez sélectionner un champ de plus que le plafond des classes. Dans cet exemple, sélectionnez la plage C1:C6. Activez la fonction FREQUENCE dans l'Assistant Fonctions. Sélectionnez la plage Données dans (A1:A11), puis la plage Classes dans laquelle vous avez saisi les limites des classes (B1:B6). Cochez la case Matrice, puis cliquez sur OK. Les valeurs des fréquences s'affichent dans la plage C1:C6.

Informations complémentaires en haut de cette page.

## INVERSEMAT

Renvoie la matrice inverse.

#### Syntaxe

INVERSEMAT(matrice)

matrice représente une matrice carrée à inverser.

Informations complémentaires en haut de cette page.

#### Exemple

Sélectionnez une plage de cellules carrée, puis INVERSEMAT. Sélectionnez la matrice de résultat, cochez la case Matrice, puis cliquez sur OK.

## LOGREG

Cette fonction calcule l'ajustement des données saisies sous forme de courbe de régression exponentielle (y=b*m^x).

#### Syntaxe

LOGREG(données_Y[;données_X[;type_fonction[;stats]]])

données_Y représente la matrice de données Y.

données_X (facultatif) représente la matrice de données X.

type_fonction (facultatif). Si type_fonction = 0, les fonctions de la forme y = m^x seront calculées. Sinon, les fonctions y = b*m^x seront calculées.

stats (facultatif). Si stats=0, seul le coefficient de régression est calculé.

Dans les fonctions LibreOffice Calc, les paramètres marqués comme "facultatifs" peuvent être ignorés lorsqu'ils ne sont pas suivis d'autres paramètres. Par exemple, dans une fonction comportant quatre paramètres, où les deux derniers paramètres sont marqués comme "facultatifs", le paramètre 4 ou les paramètres 3 et 4 peuvent être ignorés, mais le paramètre 3 seul ne peut être ignoré.

Informations complémentaires en haut de cette page.

#### Exemple

Voir DROITEREG. Toutefois, aucune somme des carrés ne sera renvoyée.

## MUNIT

Renvoie la matrice carrée unitaire d'une certaine taille. Une matrice unitaire est une matrice carrée dans laquelle les principaux éléments en diagonale sont égaux à 1 et tous les autres éléments à 0.

#### Syntaxe

MUNIT(dimensions)

dimensions désigne la taille de la matrice.

Une introduction générale à l'utilisation des fonctions de matrice est disponible en haut de cette page.

#### Exemple

Sélectionnez une plage carré à l'intérieur d'une feuille de calcul, par exemple la plage A1 à E5.

Sans désélectionner la plage, sélectionnez la fonction MUNIT. Cochez la case Matrice. Entrez les dimensions souhaitées pour l'unité de matrice, dans ce cas 5, et cliquez sur OK.

Vous pouvez également saisir la formule =MUNIT(5) dans la dernière cellule de la plage sélectionnée (E5), et appuyer sur Maj+Commande+Entrée Maj+Ctrl+Entrée.

Une matrice unitaire composée de la plage A1:E5 s'affiche.

Informations complémentaires en haut de cette page.

## PRODUITMAT

Calcule le produit de deux matrices. Le nombre de colonnes de la matrice 1 doit correspondre au nombre de lignes de la matrice 2. La matrice carrée possède un nombre égal de lignes et de colonnes.

#### Syntaxe

PRODUITMAT(matrice1;matrice2)

matrice1 représente la première matrice utilisée pour le calcul du produit de la matrice.

matrice2 représente la seconde matrice du calcul avec le même nombre de lignes.

Informations complémentaires en haut de cette page.

#### Exemple

Sélectionnez une plage carrée. Choisissez la fonction PRODUITMAT. Sélectionnez matrice1, puis matrice2. À l'aide de l'Assistant Fonctions, cochez la case Matrice. Cliquez sur OK. La matrice obtenue s'affiche dans la première plage sélectionnée.

## SOMME.X2MY2

Renvoie la somme de la différence des carrés des valeurs correspondantes dans les deux matrices.

#### Syntaxe

SOMME.X2MY2(matrice_X;matrice_Y)

matrice_X représente la première matrice dont les éléments doivent être mis au carré et additionnés.

matrice_Y représente la seconde matrice dont les éléments doivent être mis au carré et soustraits.

Informations complémentaires en haut de cette page.

## SOMME.X2PY2

Renvoie la somme des sommes des carrés des valeurs correspondantes aux deux matrices.

#### Syntaxe

SOMME.X2PY2(matrice_X;matrice_Y)

matrice_X représente la première matrice dont les éléments doivent être mis au carré et additionnés.

matrice_Y représente la seconde matrice dont les éléments doivent être mis au carré et ajoutés.

Informations complémentaires en haut de cette page.

## SOMME.XMY2

Ajoute les carrés de la variance entre les valeurs correspondantes aux deux matrices.

#### Syntaxe

SOMME.XMY2(matrice_X;matrice_Y)

matrice_X représente la première matrice dont les éléments doivent être soustraits et mis au carré.

matrice_Y représente la seconde matrice dont les éléments doivent être soustraits et mis au carré.

Informations complémentaires en haut de cette page.

## SOMMEPROD

Multiplie les éléments correspondants dans les matrices données et renvoie la somme de ces produits.

#### Syntaxe

SOMMEPROD(matrice1[;matrice2;][...;[matrice255]])

matrice1[;matrice2;][...;[matrice255]] représente les matrices dont les éléments correspondants doivent être multipliés.

Au moins une matrice doit faire partie de la liste d'arguments. Si une seule matrice est donnée, tous les éléments de la matrice sont additionnés. Si plusieurs matrices sont données, elles doivent toutes être de même taille.

#### Exemple

| A | B | C | D
1 | 2 | 3 | 4 | 5
2 | 6 | 7 | 8 | 9
3 | 10 | 11 | 12 | 13

=SOMMEPROD(A1:B3;C1:D3) renvoie 397.

Calcul : A1*C1 + B1*D1 + A2*C2 + B2*D2 + A3*C3 + B3*D3

Vous pouvez utiliser la fonction SOMMEPROD pour calculer le produit scalaire de deux vecteurs.

SOMMEPROD renvoie un seul nombre. Il n'est donc pas nécessaire de saisir la fonction sous forme de fonction de matrice.

Informations complémentaires en haut de cette page.

## TENDANCE

Renvoie les valeurs en suivant une tendance linéaire.

#### Syntaxe

TENDANCE(données_Y[;données_X[;nouvelles_données_X[;type_linéaire]]])

données_Y représente la matrice de données Y.

données_X (facultatif) représente la matrice de données X.

nouvelles_données_X (facultatif) représente la matrice de données X qui sont utilisées pour recalculer les valeurs.

type_linéaire (facultatif). Si type_linéaire=0, alors les courbes seront calculées à travers le point zéro. Sinon, les courbes décalées seront aussi calculées. La position par défaut est type_linéaire <> 0.

Dans les fonctions LibreOffice Calc, les paramètres marqués comme "facultatifs" peuvent être ignorés lorsqu'ils ne sont pas suivis d'autres paramètres. Par exemple, dans une fonction comportant quatre paramètres, où les deux derniers paramètres sont marqués comme "facultatifs", le paramètre 4 ou les paramètres 3 et 4 peuvent être ignorés, mais le paramètre 3 seul ne peut être ignoré.

Informations complémentaires en haut de cette page.

#### Exemple

Dans la feuille de calcul, sélectionnez la plage dans laquelle devront s'afficher les données de tendance. Sélectionnez la fonction. Saisissez les données de sortie ou sélectionnez-les avec la souris. Cochez la case Matrice, puis cliquez sur OK. Les données de tendance calculées à partir des données de sortie s'affichent.

## TRANSPOSE

Transpose les lignes et les colonnes d'une matrice.

#### Syntaxe

TRANSPOSE(matrice)

matrice correspond à la matrice, dans la feuille de calcul, qui doit être transposée.

Une introduction générale à l'utilisation des fonctions de matrice est disponible en haut de cette page.

#### Exemple

Dans la feuille de calcul, sélectionnez la plage de cellules pouvant accueillir la matrice transposée. Si la matrice d'origine compte n lignes et m colonnes, vous devez sélectionner une plage comportant au minimum m lignes et n colonnes. Ensuite, saisissez directement la formule, sélectionnez la matrice d'origine et appuyez sur Maj+Commande+Entrée Maj+Ctrl+Entrée. Si vous utilisez l'assistant Fonctions, cochez la case Matrice. La matrice transposée s'affiche dans la plage de destination sélectionnée. Elle est automatiquement protégée contre les modifications.

| A | B | C | D
1 | 2 | 3 | 4 | 5
2 | 6 | 7 | 8 | 9

La table ci-dessus est de 2 lignes et 4 colonnes. Afin de pouvoir la transposer, vous devez sélectionner 4 lignes et 2 colonnes. En imaginant que vous souhaitez transposer la table ci-dessus dans la plage A7:B10 (4 lignes, 2 colonnes) vous devez sélectionner la plage entière, puis saisir les valeurs suivantes :

TRANSPOSE (A1:D2)

Puis assurez-vous de les saisir comme formule de matrice avec Maj+Commande+Entrée Maj+Ctrl+Entrée. Le résultat sera le suivant :

| A | B
7 | 2 | 6
8 | 3 | 7
9 | 4 | 8
10 | 5 | 9

Rubriques connexes

Fonctions par catégories